DeepTip: наводим порядок в панели быстрого запуска Mountain Lion

Панель быстрого запуска в Mountain Lion довольно удобна, вместе с тем сложно что-либо убрать из неё, если вы скачали это не из App Store. Если Launchpad Control неприемлем для вас, этот способ может помочь.

Перетяните одно и более приложений на иконку AppleScript, описанному ниже, и значок этого приложения удалится из панели быстрого запуска. Вы можете перетягивать ярлыки либо указывать вручную приложения, которые хотите удалить. Скрипт умеет отслеживать некоторые ошибки и сообщать о них. Удаляются только ярлыки, сами приложения остаются на месте.

Вы можете проверить работу программы на самой же себе. В AppleScript Editor сохраните скрипт как приложение, перетяните приложение в панель быстрого запуска, откройте панель быстрого запуска, запустите приложение, перетяните иконку приложения из панели быстрого запуска в открывшееся окно и нажмите Enter, когда он предложит. Иконка удалится из панели быстрого запуска.

on open the_items
	my Lighten_LaunchPad(the_items)
end open

on Lighten_LaunchPad(the_items)
	repeat with the_item in the_items
		set the_item to the_item as alias
		--try
		tell application "Finder"
			set nameString to name of the_item
			set sost to (my get_the_name(nameString)) as string
		end tell
		display dialog "Are you sure you want to remove \"" & sost & "\" from the Launchpad? The app itself won't be deleted."
		try
			set my_command to "sqlite3 ~/Library/Application\\ Support/Dock/" & "*.db \"DELETE from apps WHERE title=" & (quoted form of sost) & ";\";osascript -e 'tell application \"Dock\" to quit'"
			do shell script my_command
		on error the error_message number the error_number
			activate
			if the error_number is not -128 then
				if the error_number is 1 then
					set the error_text to "Error: " & the error_number & ". " & "You probably have too many old versions of the LaunchPad database file." & return & return & " To fix that, move some old ones out of ~/Library/Application Support/Dock. You can safely move any file with a name that ends with \".db\" or \".db.backup\" except for the most recently modified one." & return & return & "Do you want me to open that folder for you?"
					display dialog the error_text buttons {"Yes, please open it.", "Cancel"} default button 1
					if button returned of the result is "Yes, please open it." then
						do shell script "open" & space & quoted form of POSIX path of (path to application support folder from user domain) & "Dock"
					end if
					error number -128
				else
					set the error_text to "Error: " & the error_number & ". " & the error_message
					display dialog the error_text buttons {"Cancel"} default button 1
				end if
			else
				error number -128
			end if
		end try
	end repeat
	display dialog "All done!" buttons {"OK"} default button 1
end Lighten_LaunchPad

on get_the_name(nameString)
	tell AppleScript
		set olD to text item delimiters
		set text item delimiters to "."
		set reqItem to -1
		if last item of nameString = "." then set reqItem to -2
		set theName to text item reqItem of nameString
		--try
		set theNameNoExt to ((text items 1 through (reqItem - 1) of nameString) as string)
		set text item delimiters to olD
		return {theNameNoExt}
	end tell
end get_the_name

on run
	set the_items to ((choose file) as list)
	Lighten_LaunchPad(the_items)
end run

Источник: Mac OS X Hints

Обсуждение

27.03.2013, 01:06
С'est charmant. Однако же http://deepapple.com/news/40715.html.
Оставить сообщение
Обсуждение на форуме целиком